PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

pkgname=nanolist-git
_pkgname=nanolist
pkgdesc="mailing lists - the unix way"
pkgver=r19.ba179b7
pkgrel=1
arch=('i686' 'x86_64')
url='https://github.com/eXeC64/nanolist'
source=('git+git://github.com/eXeC64/nanolist')
depends=()
makedepends=('go')
sha1sums=('SKIP')
license=('BSD 3-Clause License')

pkgver() {
  cd "$srcdir/$_pkgname"
  ( set -o pipefail
    git describe --long --tags 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

build(){
  cd "$srcdir/$_pkgname"
  GO111MODULE=on go build -o "$srcdir/bin/nanolist"
}

package() {
  cd "$srcdir/bin"
  install -Dm755 'nanolist' "$pkgdir/usr/bin/nanolist"
  cd "$srcdir/$_pkgname"
  install -Dm644 'README.md' "$pkgdir/usr/share/doc/$pkgname/README.md"
  install -Dm644 'LICENSE' "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  sed -n '/^```ini$/,/^```$/{//!p}' README.md > "$pkgdir/usr/share/doc/$pkgname/nanolist.ini.sample"
}