blob: 9298cf84ed5ed468ca02db8f851e7dd3ba73e03d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Klaus Alexander Seistrup <klaus@seistrup.dk>
# Contributor: Sebastian Wiesner <sebastian@swsnr.de>
# Contributor: Vlad Petrov <ejiek@mail.ru>
# -*- sh -*-
pkgname='nb'
pkgver=7.11.0
pkgrel=2
pkgdesc="A command-line note-taking, bookmarking, archiving, and knowledge base application"
arch=('any')
url="https://github.com/xwmx/${pkgname}"
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz")
license=('AGPL-3.0-or-later') # SPDX-License-Identifier: AGPL-3.0-or-later
depends=('bash' 'git')
optdepends=(
# Recommended
'bat: recommended'
'nmap: for ncat, recommended' # For ncat
'pandoc: recommended'
'ripgrep: recommended'
'tig: recommended'
'w3m: recommended'
# Additional
'ack'
'the_silver_searcher'
'catimg'
'eza'
'ffmpeg' # For ffplay
'imagemagick'
'gnupg'
'highlight'
'links'
'lynx'
'mc'
'mpg123'
'mplayer'
'poppler' # For pdftotext
'python-pygments'
'ranger'
'readability-cli'
'ripgrep-all'
'termpdf.py-git'
'vifm'
)
package() {
cd "${pkgname}-${pkgver}"
# Be more verbose if standard output is a TTY
test -t 1 && _v='v' || _v=''
install -${_v}Dm0755 "${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -${_v}Dm0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -${_v}Dm0644 README.md "$pkgdir/usr/share/doc/${pkgname}/README.md"
# Completions
install -${_v}Dm0644 etc/nb-completion.bash "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
install -${_v}Dm0644 etc/nb-completion.fish "${pkgdir}/usr/share/fish/vendor_completions.d/${pkgname}.fish"
install -${_v}Dm0644 etc/nb-completion.zsh "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
# Plugins
install -${_v}Dm0644 -t "${pkgdir}/usr/share/nb/plugins/" plugins/*
# Extras (prefixed with "nb-")
for _extra in bookmark notes; do
install -${_v}Dm0755 "bin/$_extra" "${pkgdir}/usr/bin/${pkgname}-${_extra}"
done
}
sha256sums=(
'20582072c36da3c4f05a53634cea4470464266e6b764b06828b297ca16743800'
)
b2sums=(
'24cb6c3afcc339c964d9eef7a7a05b1a9f990c61e8ae32a8ed9d745c0381da4a34336aff5630ae243a61f594076bd6852ea86effe1000272cd57cbe062785657'
)
# eof
|