blob: 247e1a126c5d763d5726123b7d58d34fa66155c0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: Thomas Weißschuh <thomas t-8ch de>
pkgname=nbdkit
pkgver=1.24.4
pkgrel=2
pkgdesc="NBD server toolkit"
arch=('i686' 'x86_64')
url="https://gitlab.com/nbdkit/nbdkit/"
license=('custom: BSD')
depends=()
optdepends=(
'lua'
'tcl'
'perl'
'rust'
'go'
'python'
'ocaml'
'libnbd'
'libvirt'
'curl'
'libguestfs'
'libssh'
'libtorrent-rasterbar'
'libselinux'
)
checkdepends=('qemu-headless')
validpgpkeys=('F7774FB1AD074A7E8C8767EA91738F73E1B768A0')
_dldir="${pkgver%.*}"
source=(
"http://download.libguestfs.org/nbdkit/${_dldir}-stable/nbdkit-${pkgver}.tar.gz"
"http://download.libguestfs.org/nbdkit/${_dldir}-stable/nbdkit-${pkgver}.tar.gz.sig"
"https://gitlab.com/nbdkit/nbdkit/-/commit/e29a0c0a2fb725ea0c3e4f363a77b2964ecea7ec.patch"
)
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -p1 < "${srcdir}"/e29a0c0a2fb725ea0c3e4f363a77b2964ecea7ec.patch
rm tests/test-ssh.sh
touch tests/test-ssh.sh
chmod +x tests/test-ssh.sh
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
autoreconf -i
./configure --prefix=/usr --sbindir=/usr/bin
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
install -m644 -D LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
make DESTDIR="$pkgdir" install
}
check() {
cd "${srcdir}/${pkgname}-${pkgver}"
make check
}
sha256sums=('e3368c51d3f08b0001af6a6d3751cb6177b6db0ca2f3d0ac8e1ed2eeb5d1b54d'
'SKIP'
'a161ec4bfcc772d90a07b92a387c00b5e1602c819ab6c87e13d6fbec1ef759ce')
|