blob: e8dbbcd8a4250c6edb60ae09896f5e521675ea3b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer : Daniel Bermond <dbermond@archlinux.org>
# Contributor: rich_o <aurua@riseup.net>
pkgname=ncmpcpp-git
pkgver=0.9.2.r20.gdc46f7a4
pkgrel=1
epoch=2
pkgdesc='An almost exact clone of ncmpc with some new features (git version)'
arch=('x86_64')
url='https://rybczak.net/ncmpcpp/'
license=('GPL-2.0-or-later')
depends=('curl' 'boost-libs' 'fftw' 'icu' 'libmpdclient' 'ncurses' 'readline' 'taglib')
makedepends=('git' 'boost')
provides=('ncmpcpp')
conflicts=('ncmpcpp')
source=('git+https://github.com/arybczak/ncmpcpp.git'
'010-ncmpcpp-use-arch-flags.patch'
'020-ncmpcpp-taglib2-fix.patch')
sha256sums=('SKIP'
'1907468f83dbd733e20e5d56b633eeee58a507f0767789fd0583e55d8761d0e7'
'8843ade2cfbdd88309a50d8e3ab186a21d4857e02ce93acef7ae5a7178fb3def')
prepare() {
patch -d ncmpcpp -Np1 -i "${srcdir}/010-ncmpcpp-use-arch-flags.patch"
patch -d ncmpcpp -Np1 -i "${srcdir}/020-ncmpcpp-taglib2-fix.patch"
ncmpcpp/autogen.sh
}
pkgver() {
git -C ncmpcpp describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}
build() {
cd ncmpcpp
export BOOST_LIB_SUFFIX=''
# http://site.icu-project.org/download/61#TOC-Migration-Issues
export CPPFLAGS+=' -DU_USING_ICU_NAMESPACE=1'
# work around deprecated TagLib::String::null from TagLib 1.12
export CXXFLAGS+=' -Wno-error=deprecated-declarations'
./configure \
--prefix='/usr' \
--enable-clock \
--enable-outputs \
--enable-visualizer \
--with-fftw \
--with-taglib
make
make -C extras
}
package() {
make -C ncmpcpp DESTDIR="$pkgdir" install
install -D -m755 ncmpcpp/extras/artist_to_albumartist -t "${pkgdir}/usr/bin"
}
|