blob: 89cce86dda9e50d84bad6c9ed71c7204916af491 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Blair Bonnett <blair.bonnett at gmail>
# Contributor: Graziano Giuliani <giuliani@lamma.rete.toscana.it>
# Contributor: Graziano Giuliani <graziano.giuliani@gmail.com>
pkgname=nco
pkgver=5.2.4
pkgrel=1
pkgdesc="netCDF Operators allow users to manipulate and analyse data stored in NetCDF files"
url="http://nco.sourceforge.net/"
license=('BSD-3-Clause')
depends=('netcdf' 'udunits' 'gsl' 'curl' 'ccr')
makedepends=('antlr2')
arch=('x86_64')
options=('!libtool')
source=(
"$pkgname-$pkgver.tar.gz::https://github.com/nco/nco/archive/$pkgver.tar.gz"
'use_antlr2.patch'
)
sha256sums=(
'44efa9151825487fa0562fa5c6d68837624059a8e2da9d15c83ceb4d498f7902'
'db3e62369ab803d6aad302ff4327b081963dfb2641c82aad51d2f800b0c3db4c'
)
prepare() {
cd "$srcdir/$pkgname-$pkgver"
patch -p0 -i "$srcdir/use_antlr2.patch"
}
build() {
cd "$srcdir/$pkgname-$pkgver"
./configure \
--prefix=/usr \
--with-hdf5-plugin-path=/usr/lib/hdf5/plugin \
--enable-ccr
make
}
check() {
cd "$srcdir/$pkgname-$pkgver"
make check
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install install-html
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
# vim:set ts=2 sw=2 et:
|