blob: 91212aded71cd98bfdd53adc0ae70a7fc1b22c49 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=ncurses-git
pkgver=6.1.20200111.r0.g431911e0
pkgrel=1
pkgdesc="Screen handling and optimization package"
arch=('i686' 'x86_64')
url="https://invisible-island.net/ncurses/ncurses.html"
license=('MIT')
depends=('glibc')
makedepends=('git')
provides=('ncurses' 'libncurses++w.so' 'libformw.so' 'libmenuw.so' 'libpanelw.so' 'libncursesw.so')
conflicts=('ncurses')
options=('staticlibs')
source=("git+https://github.com/ThomasDickey/ncurses-snapshots.git")
sha256sums=('SKIP')
pkgver() {
cd "ncurses-snapshots"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g;s/_/./g'
}
build() {
cd "ncurses-snapshots"
./configure \
--prefix="/usr" \
--mandir="/usr/share/man" \
--enable-pc-files \
--enable-widec \
--with-cxx-shared \
--with-pkg-config-libdir="/usr/lib/pkgconfig" \
--with-shared \
--without-debug
make
}
package() {
cd "ncurses-snapshots"
make DESTDIR="$pkgdir" install
install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/ncurses"
# fool packages looking to link to non-wide-character ncurses libraries
for lib in ncurses ncurses++ form panel menu; do
echo "INPUT(-l${lib}w)" > "$pkgdir/usr/lib/lib${lib}.so"
ln -s "${lib}w.pc" "$pkgdir/usr/lib/pkgconfig/${lib}.pc"
done
for lib in tic tinfo; do
echo "INPUT(libncursesw.so.${pkgver:0:1})" > "$pkgdir/usr/lib/lib${lib}.so"
ln -s "libncursesw.so.${pkgver:0:1}" "$pkgdir/usr/lib/lib${lib}.so.${pkgver:0:1}"
ln -s "ncursesw.pc" "$pkgdir/usr/lib/pkgconfig/${lib}.pc"
done
# some packages look for -lcurses during build
echo 'INPUT(-lncursesw)' > "$pkgdir/usr/lib/libcursesw.so"
ln -s "libncurses.so" "$pkgdir/usr/lib/libcurses.so"
}
|