blob: 3f86df0e2bc37cb4e8e122c696eb483a4f02b69d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Sebastian Lau <lauseb644@gmail.com>
# Contributor: American_Jesus <american.jesus.pt AT gmail DOT com>
_mintrel=rafaela
pkgname=nemo-dropbox
pkgver=2.6.0
pkgrel=2
pkgdesc="Dropbox for Linux - Nemo extension"
arch=('i686' 'x86_64')
url="https://github.com/linuxmint/nemo-extensions"
license=('custom:CC-BY-ND-3' 'GPL')
depends=('libnotify' 'nemo' 'hicolor-icon-theme')
makedepends=('python2-docutils' 'python2' 'pygtk')
conflicts=('nautilus-dropbox' 'caja-dropbox')
optdepends=('dropbox: Dropbox suport')
install=${pkgname}.install
options=('!libtool' '!emptydirs')
source=("http://packages.linuxmint.com/pool/main/n/$pkgname/${pkgname}_${pkgver}%2b${_mintrel}.tar.gz")
#http://packages.linuxmint.com/pool/main/n/$pkgname/$pkgname_$pkgver%2b$_mintrel.tar.gz
md5sums=('c5889e19d865337309bb85a95b3e64cc')
build() {
cd ${pkgname}-${pkgver}+${_mintrel}
# sed -i "s|AM_CONFIG_HEADER|AC_CONFIG_HEADERS|g" configure.in
autoreconf -fi
sed -i "s/python/python2/" configure dropbox.in Makefile.in rst2man.py
# since python2-docutils, rst2man.py is named "rst2man2.py"
sed -i "s:rst2man.py:/usr/bin/rst2man2.py:" configure
PYTHON=python2 ./configure --prefix=/usr --sysconfdir=/etc
make
}
package() {
cd ${pkgname}-${pkgver}+${_mintrel}
make DESTDIR="${pkgdir}" install
# remove executables and depend on 'dropbox' package
rm "${pkgdir}/usr/bin/dropbox"
rm "${pkgdir}/usr/share/applications/dropbox.desktop"
rm "${pkgdir}/usr/share/man/man1/dropbox.1"
# install the common license
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}
|