blob: 54277082175611d5d41b2e18f07773d8e9b9dbdb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Sebastian Lau <lauseb644 _at_ gmail.com>
# Contributor: twa022 <twa022 at gmail dot com>
# Contributor: American_Jesus <american.jesus.pt AT gmail DOT com>
pkgname=nemo-dropbox
pkgver=3.6.0
pkgrel=1
pkgdesc="Dropbox for Linux - Nemo extension"
arch=('i686' 'x86_64')
url="https://github.com/linuxmint/nemo-extensions"
license=('custom:CC-BY-ND-3' 'GPL')
depends=('nemo>=3.2' 'dropbox')
makedepends=('glib2')
install=${pkgname}.install
options=('!libtool' '!emptydirs')
source=("nemo-extensions-$pkgver.tar.gz::https://github.com/linuxmint/nemo-extensions/archive/$pkgver.tar.gz"
"01-Remove-python-dependencies.patch"
"02-Makefile.patch")
md5sums=('9cb93de02de5fbea0aa9fe3114c551ee'
'4e607465244108d0eae5422ed04a7ac1'
'fb0f04ed594b62bc9bf7256d18a4d6c2')
prepare() {
cd "${srcdir}/nemo-extensions-${pkgver}/${pkgname}"
patch -uNp2 -r- -i ../../01-Remove-python-dependencies.patch
patch -uNp2 -r- -i ../../02-Makefile.patch
}
build() {
cd "${srcdir}/nemo-extensions-${pkgver}/${pkgname}"
autoreconf -fi
./configure --prefix=/usr --sysconfdir=/etc
make
}
package() {
cd "${srcdir}/nemo-extensions-${pkgver}/${pkgname}"
make DESTDIR="${pkgdir}" install
# install the common license
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}
|