blob: 1a53e38f35842de3668a106eec57b0ded796cb6b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Contributor: Mark Carter <alt.mcarter@gmail.com>
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
pkgname=neoleo-git
pkgver=11.0.r9.g33b25b4
pkgrel=3
pkgdesc="Lightweight curses spreadsheet based on GNU oleo"
arch=('i686' 'x86_64')
url="https://github.com/blippy/neoleo"
conflicts=(${pkgname%-git})
provides=(${pkgname%-git})
license=('GPL')
depends=('ncurses')
makedepends=('git')
source=("git+$url.git" io-curses.patch)
options=('!makeflags')
sha256sums=('SKIP'
'b1c89e5b4f9eaf887c8bdb9d0a54d2b150869c71a6018fae700f119ca43a0983')
pkgver() {
cd ${pkgname%-git}
git describe --tags | sed 's+-+.r+' |tr - . | cut -c2-
}
prepare() {
cd ${pkgname%-git}
git apply "$srcdir"/io-curses.patch
}
build() {
cd ${pkgname%-git}
autoreconf -iv
LIBS+="-lstdc++fs" ./configure --prefix=/usr
make
}
package() {
cd ${pkgname%-git}
make DESTDIR="$pkgdir/" install
}
|