blob: 709d6fbed6dc311dc2dbc32079b7fc47ff131043 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Sean Haugh <seanphaugh@gmail.com>
# Contributor: Chris Salzberg <chris@dejimata.com>
_pkgname=neomutt
pkgname=neomutt-git
pkgver=20171215.r144.gb7da81ad
pkgrel=1
pkgdesc='The New Mutt: powerful text-based mail client with all the best feature patches'
url='http://www.neomutt.org/'
license=('GPL')
source=('git+https://github.com/neomutt/neomutt.git#branch=master')
sha256sums=('SKIP')
arch=('i686' 'x86_64')
depends=('notmuch-runtime' 'lua' 'python')
optdepends=('urlview: for url menu')
makedepends=('git' 'gnupg' 'libxslt')
conflicts=('neomutt')
provides=('neomutt')
pkgver() {
cd "${srcdir}/${_pkgname}"
# Get the version number.
git describe --long --tags | sed 's/^neomutt-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "${srcdir}/${_pkgname}"
# Configure the build.
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib \
--enable-debug \
--enable-pgp \
--enable-gpgme \
--enable-notmuch \
--enable-lua \
--with-gss=/usr \
--with-ssl=/usr \
--with-sasl=/usr \
--with-idn=/usr \
--with-gdbm=/usr
# Build it!
make
}
package() {
cd "${srcdir}/${_pkgname}"
# Install the program.
make DESTDIR="${pkgdir}" install
}
# vim: ft=sh ts=2 sw=2 et
|