blob: 1ed421e4bba3a8a347e1fa419a5662c4869a589a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Nico <d3sox at protonmail dot com>
pkgname=nerd-fonts-sf-mono
pkgver=2.3.2
pkgrel=1
_fontver=10
pkgdesc="Monospaced variant of San Francisco. Sourced directly from Apple, patched with the Nerd Fonts Patcher"
arch=('any')
url='https://developer.apple.com/fonts/'
license=('custom')
makedepends=('git' 'p7zip' 'python' 'fontforge' 'subversion' 'parallel')
conflicts=('nerd-fonts-sf-mono')
provides=('nerd-fonts-sf-mono')
source=("SF-Mono-$_fontver.dmg::https://developer.apple.com/design/downloads/SF-Mono.dmg" "font-patcher-$pkgver::https://raw.githubusercontent.com/ryanoasis/nerd-fonts/v$pkgver/font-patcher" "svn+https://github.com/ryanoasis/nerd-fonts/tags/v$pkgver/src/glyphs")
sha256sums=('abaf6d62cd5b17ae1837ab40a35386733a3f603cf641a84cf59b1d7fb4caac39'
'3b733a8030c9c85fa369714eaeaddef766ed788717eb38334903c30f1523bd27'
'SKIP')
build() {
_patcher="font-patcher-$pkgver"
# remove previous files
rm -rf SFMonoFonts
# extract dmg
7z x "SF-Mono-$_fontver.dmg"
# extract pkg
bsdtar xvPf "SFMonoFonts/SF Mono Fonts.pkg"
bsdtar xvPf "SFMonoFonts.pkg/Payload"
# patch fonts
mkdir -p "$srcdir/patched"
printf "%b" "\e[1;33m==> WARNING: \e[0mNow patching all fonts. This will take very long...\n"
# patch fonts quiet with complete single-width glyphs
parallel -j$(nproc) python "$srcdir/$_patcher" --glyphdir "$srcdir/glyphs/" -q -c -s {} -out "$srcdir/patched" &> /dev/null ::: "$srcdir/Library/Fonts"/*.otf
}
package() {
# install fonts
install -d "$pkgdir/usr/share/fonts/apple"
install -m644 "patched"/*.otf "$pkgdir/usr/share/fonts/apple/"
}
|