PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

# Maintainer: Tony Lambiris <tony@criticalstack.com>

pkgname=netcap-git
pkgver=v0.4.7.r35.ge0009ae6
pkgrel=1
pkgdesc='A framework for secure and scalable network traffic analysis'
url="https://github.com/dreadl0ck/netcap"
arch=('x86_64')
license=('GPL3')
makedepends=('git' 'go')
conflicts=('netcap')
provides=('netcap')
source=("${pkgname}::git+${url}")
sha256sums=('SKIP')

pkgver() {
	cd "${srcdir}/${pkgname}"

	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
	cd "${srcdir}/${pkgname}"

	install -m755 -d "${srcdir}/go/src/github.com/dreadl0ck/"
	ln -sf "${srcdir}/${pkgname}" "${srcdir}/go/src/github.com/dreadl0ck/netcap"

	cd "${srcdir}/go/src/github.com/dreadl0ck/netcap"

	export GOPATH="${srcdir}/go"
	go get -v ./...
}

build() {
	cd "${srcdir}/go/src/github.com/dreadl0ck/netcap"

	mkdir -p build

	export GOPATH="${srcdir}/go"
	for i in cmd/*; do
		msg2 "Compiling $i..."

		go build \
			-ldflags "-s -w" \
			-gcflags="all=-trimpath=${GOPATH}/src" \
			-asmflags="all=-trimpath=${GOPATH}/src" \
			-o "build/net.$(basename $i)" "./$i"
	done
}

package() {
	cd "${srcdir}/go/src/github.com/dreadl0ck/netcap"

	install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

	cd build
	find . -type f -name 'net.*' -exec install -Dm755 "{}" "${pkgdir}/usr/bin/{}" \;
}