blob: b39472b3ba92c07f426fc7e4cbd8e8afc44e7720 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Maintainer: zxp19821005 <zxp19821005 at 163 dot com>
pkgname=netron-git
_pkgname=Netron
pkgver=7.6.4.r5.g83f4234
_electronversion=30
_nodeversion=20
pkgrel=1
pkgdesc="Visualizer for neural network, deep learning and machine learning models"
arch=('any')
url="https://netron.app/"
_ghurl="https://github.com/lutzroeder/netron"
license=('MIT')
conflicts=("${pkgname%-git}")
provides=("${pkgname%-git}=${pkgver%.r*}")
depends=(
"electron${_electronversion}"
)
makedepends=(
'npm'
'git'
'nvm'
'gendesk'
'python'
'python-setuptools'
'python-build'
'python-installer'
'python-wheel'
)
optdepends=(
'python-onnx: serializing ONNX models'
'python-pytorch: serializing PyTorch models'
)
source=(
"${pkgname//-/.}::git+${_ghurl}.git"
"${pkgname%-git}.sh")
sha256sums=('SKIP'
'05762c556c85a4423b28600ccbbe7b7dcdd3d1be526ef4a588a510671fa6c62a')
pkgver() {
cd "${srcdir}/${pkgname//-/.}"
git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/v//g'
}
_ensure_local_nvm() {
export NVM_DIR="${srcdir}/.nvm"
source /usr/share/nvm/init-nvm.sh || [[ $? != 1 ]]
nvm install "${_nodeversion}"
nvm use "${_nodeversion}"
}
build() {
sed -e "s|@electronversion@|${_electronversion}|" \
-e "s|@appname@|${pkgname%-git}|g" \
-e "s|@runname@|app.asar|g" \
-e "s|@options@|env ELECTRON_OZONE_PLATFORM_HINT=auto|g" \
-i "${srcdir}/${pkgname%-git}.sh"
_ensure_local_nvm
gendesk -q -f -n --categories="Development" --name="${_pkgname}" --exec="${pkgname%-git} %U"
cd "${srcdir}/${pkgname//-/.}"
export npm_config_build_from_source=true
export npm_config_cache="${srcdir}/.npm_cache"
export ELECTRON_SKIP_BINARY_DOWNLOAD=1
export SYSTEM_ELECTRON_VERSION="$(electron${_electronversion} -v | sed 's/v//g')"
export npm_config_target="${SYSTEM_ELECTRON_VERSION}"
export ELECTRONVERSION="${_electronversion}"
export npm_config_disturl=https://registry.npmmirror.com/-/binary/node/
HOME="${srcdir}/.electron-gyp"
if [ `curl -s ipinfo.io/country | grep CN | wc -l ` -ge 1 ];then
export npm_config_registry=https://registry.npmmirror.com
export npm_config_electron_mirror=https://registry.npmmirror.com/-/binary/electron/
export npm_config_electron_builder_binaries_mirror=https://registry.npmmirror.com/-/binary/electron-builder-binaries/
else
echo "Your network is OK."
fi
rm -rf dist node_modules
sed 's|"AppImage", "snap"|"dir"|g' -i package.json
sed '/python -m pip/d;/--mac /d;/--win /d;/--linux snap/d;s|--linux appimage --x64|--dir|g' -i package.js
npm install
npm run build
}
package() {
install -Dm755 "${srcdir}/${pkgname%-git}.sh" "${pkgdir}/usr/bin/${pkgname%-git}"
install -Dm644 "${srcdir}/${pkgname//-/.}/dist/linux-"*/resources/app.asar -t "${pkgdir}/usr/lib/${pkgname%-git}"
install -Dm644 "${srcdir}/${pkgname//-/.}/publish/icon.png" "${pkgdir}/usr/share/pixmaps/${pkgname%-git}.png"
install -Dm644 "${srcdir}/${pkgname%-git}.desktop" -t "${pkgdir}/usr/share/applications"
install -Dm644 "${srcdir}/${pkgname//-/.}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|