blob: 5f7021aa4e6cd5776fb6ff46ac17d1e102d197e4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
|
# Maintainer: Alexey D. <lq07829icatm@rambler.ru>
# Contributor: DaZ <daz.root+arch@gmail.coM>
# Contributor: Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinxu.org>
# Contributor: Wael Nasreddine <gandalf@siemens-mobiles.org>
# Contributor: Tor Krill <tor@krill.nu>
# Contributor: Will Rea <sillywilly@gmail.com>
# Contributor: Valentine Sinitsyn <e_val@inbox.ru>
# Contributor: Chris Cromer <chris@cromer.cl>
pkgname=networkmanager-consolekit
pkgver=1.10.5dev+3+g5159c34ea
pkgrel=1
_pppver=2.4.7
pkgdesc="NetworkManager with ConsoleKit support for non-systemd systems and user applications"
arch=('i686' 'x86_64')
license=('GPL' 'LGPL2.1')
url="https://wiki.gnome.org/Projects/NetworkManager"
depends=("libnm-glib>=$pkgver" 'iproute2' 'polkit-consolekit' 'consolekit'
'wpa_supplicant' 'libsoup' 'libmm-glib' 'libnewt' 'libndp' 'libteam'
'bluez-libs' 'curl')
makedepends=('intltool' 'dhclient' 'iptables' 'gobject-introspection' 'gtk-doc'
"ppp=$_pppver" 'modemmanager' 'vala' 'perl-yaml' 'python-gobject'
'git' 'jansson' 'glib2-docs' 'dhcpcd')
optdepends=('modemmanager: for modem management service'
'dhclient: External DHCP client'
'dhcpcd: alternative DHCP client'
'dnsmasq: connection sharing'
'bluez: bluetooth support'
'openresolv: resolvconf support'
'ppp: dialup connection support')
provides=("networkmanager=$pkgver")
replaces=('networkmanager')
conflicts=('networkmanager')
backup=('etc/NetworkManager/NetworkManager.conf')
groups=('gnome')
install=networkmanager.install
_commit=5159c34ea8923bf0c17fd31e183c5803b72b97f3 # nm-1-10
source=(#https://download.gnome.org/sources/NetworkManager/${pkgver:0:3}/NetworkManager-$pkgver.tar.xz
"git+https://anongit.freedesktop.org/git/NetworkManager/NetworkManager#commit=$_commit"
0001-nmp-netns-Mount-proc-in-the-new-namespace.patch
NetworkManager.conf
networkmanager.rc
20-connectivity.conf
)
sha256sums=('SKIP'
'9be1576cce4eb36697a13a1edd15faed66393f97ab5df2c19650989cd0b644a0'
'535f9c54ee29c35ca7b44c15f8de2e781c10d6f3324338c483bef360ad777efc'
'e39a2a0401518abd1d1d060200e2ca0f0854cdc49a5cb286919be177a7cd90fc'
'477d609aefd991c48aca93dc7ea5a77ebebf46e0481184530cceda4c0d8d72c6')
prepare() {
cd NetworkManager
# Fix test_netns_general in our containers
patch -Np1 -i ../0001-nmp-netns-Mount-proc-in-the-new-namespace.patch
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd NetworkManager
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
runstatedir=/run \
--sbindir=/usr/bin \
--libexecdir=/usr/lib \
--disable-ifcfg-rh \
--disable-ifcfg-suse \
--disable-ifnet \
--disable-ifupdown \
--disable-lto \
--disable-more-logging \
--disable-more-warnings \
--disable-static \
--enable-bluez5-dun \
--enable-concheck \
--enable-config-plugin-ibft \
--enable-gtk-doc \
--enable-introspection \
--enable-json-validation \
--enable-ld-gc \
--enable-modify-system \
--enable-polkit \
--enable-polkit-agent \
--enable-teamdctl \
--enable-tests=no \
--enable-wifi \
--with-config-dhcp-default=internal \
--with-config-dns-rc-manager-default=symlink \
--with-config-logging-backend-default=syslog \
--with-config-plugins-default=keyfile,ibft \
--with-crypto=nss \
--with-dbus-sys-dir=/usr/share/dbus-1/system.d \
--with-dhclient=/usr/bin/dhclient \
--with-dhcpcd-supports-ipv6 \
--with-dhcpcd=/usr/bin/dhcpcd \
--with-dnsmasq=/usr/bin/dnsmasq \
--with-dnssec-trigger=/usr/lib/dnssec-trigger/dnssec-trigger-script \
--with-hostname-persist=default \
--with-iptables=/usr/bin/iptables \
--with-kernel-firmware-dir=/usr/lib/firmware \
--with-libnm-glib \
--with-modem-manager-1 \
--with-nmcli \
--with-nmtui \
--with-pppd-plugin-dir=/usr/lib/pppd/$_pppver \
--with-pppd=/usr/bin/pppd \
--with-resolvconf=/usr/bin/resolvconf \
--with-session-tracking=consolekit \
--with-suspend-resume=consolekit \
--with-system-ca-path=/etc/ssl/certs \
--with-systemdsystemunitdir=/usr/lib/systemd/system \
--with-udev-dir=/usr/lib/udev \
--with-wext \
--without-libaudit \
--without-more-asserts \
--without-netconfig \
--without-ofono \
--without-selinux \
--without-systemd-journal # comment this line if want to be able to switch
# between "syslog" and "journal" logging backends
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd NetworkManager
make DESTDIR="$pkgdir" install
install -dm700 "$pkgdir"/etc/NetworkManager/system-connections
install -d "$pkgdir"/etc/NetworkManager/{conf,dnsmasq}.d
install -D -m755 "$srcdir"/networkmanager.rc "$pkgdir"/etc/rc.d/networkmanager
install -D -m644 "$srcdir"/NetworkManager.conf "$pkgdir"/etc/NetworkManager/
install -Dm644 ../20-connectivity.conf \
"$pkgdir"/usr/lib/NetworkManager/conf.d/20-connectivity.conf
# remove conflicting files from libnm, etc
rm "$pkgdir"/usr/lib/libnm*
rm -r "$pkgdir"/usr/lib/girepository-1.0
rm -r "$pkgdir"/usr/share/gir-1.0
rm -r "$pkgdir"/usr/share/gtk-doc/html/libnm*
rm -r "$pkgdir"/usr/share/vala/vapi
rm -r "$pkgdir"/usr/include
rm -r "$pkgdir"/usr/lib/pkgconfig
}
|