blob: 6211ecbfa32df44c203e2b110724133da2b08c70 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Silvio Fricke <silvio fricke@gmail.com>
# Contributor: Michel Wohlert <michel.wohlert@gmail.com>
pkgname=networkmanager-fortisslvpn-git
pkgver=1.4.1.dev.r33.g0f1b6f9
pkgrel=1
pkgdesc='NetworkManager VPN plugin for fortisslvpn - git checkout'
arch=('i686' 'x86_64')
license=('GPL')
url='https://git.gnome.org/browse/network-manager-fortisslvpn'
depends=('libnm' 'openfortivpn' 'libsecret' 'gtk4')
makedepends=('git' 'libnma' 'libnma-gtk4' 'python')
optdepends=(
'libnma-gtk4: GUI support (GTK 4)'
'libnma: GUI support (GTK 3)'
)
provides=('networkmanager-fortisslvpn')
conflicts=('networkmanager-fortisslvpn')
source=('network-manager-fortisslvpn::git+https://gitlab.gnome.org/GNOME/NetworkManager-fortisslvpn.git#branch=main')
sha256sums=('SKIP')
pkgver() {
cd network-manager-fortisslvpn/
if GITTAG="$(git describe --abbrev=0 --tags 2>/dev/null)"; then
printf '%s.r%s.g%s' \
"$(sed -e "s/^${pkgname%%-git}//" -e 's/^[-_/a-zA-Z]\+//' -e 's/[-_+]/./g' <<< ${GITTAG})" \
"$(git rev-list --count ${GITTAG}..)" \
"$(git log -1 --format='%h')"
else
printf '0.r%s.g%s' \
"$(git rev-list --count master)" \
"$(git log -1 --format='%h')"
fi
}
build() {
cd network-manager-fortisslvpn/
# autogen.sh use this variable to check if configuration is wanted.
export NOCONFIGURE=yesmeansnoconfigure
./autogen.sh
./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--libexecdir=/usr/lib/networkmanager \
--enable-more-warnings=yes \
--with-gtk4=yes \
--disable-static
make
}
package() {
cd network-manager-fortisslvpn/
make DESTDIR="${pkgdir}" install
chmod a+rx "${pkgdir}"/var/lib/NetworkManager-fortisslvpn
}
|