blob: ee4dd9470c4a3bcfff333b18f9a14496f7cfe106 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Timothée Ravier <tim@siosm.fr>
pkgname=networkmanager-qt-git
pkgver=r678.cf2d3da
pkgrel=1
pkgdesc='Qt-only wrapper for NetworkManager DBus API'
arch=('i686' 'x86_64')
url='https://projects.kde.org/projects/extragear/libs/libnm-qt'
license=('LGPL')
depends=('qt5-base' 'networkmanager')
makedepends=('extra-cmake-modules-git' 'git')
conflicts=('libnm-qt5' 'networkmanager-qt' 'libnm-qt-git')
provides=('libnm-qt5' 'networkmanager-qt')
replaces=('libnm-qt-git')
source=("git://anongit.kde.org/networkmanager-qt.git")
sha256sums=('SKIP')
pkgver() {
cd networkmanager-qt
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
mkdir -p build
}
build() {
cd build
cmake ../networkmanager-qt \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DLIB_INSTALL_DIR=lib \
-DKDE_INSTALL_USE_QT_SYS_PATHS=ON
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|