summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 495e113e13a67f739e88448c12c1ccd2fd1620cb (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
# newm - Wayland compositor
# Maintainer: Jonas Bucher <j.bucher.mn at gmail>

pkgname=newm-git
pkgver=0.3alpha
pkgrel=3
license=('MIT')
pkgdesc="Wayland compositor"
depends=(
    python3

    wayland
    libinput
    libxcb
    libxkbcommon
    opengl-driver
    pixman
    xcb-util-errors
    xcb-util-renderutil
    xcb-util-wm
    seatd
    xorg-xwayland

    python-evdev
    python-numpy
    python-imageio

    python-cairo
    python-psutil
    python-pam
    python-pyfiglet
    python-thefuzz
    python-dasbus
)
makedepends=(
    git
    sed
    python3
    meson
    ninja
    wayland-protocols
    xorgproto
)
arch=('any')
url="https://github.com/jbuchermn/newm"
source=(
	'git+https://github.com/jbuchermn/pywm.git'
	'git+https://github.com/jbuchermn/newm.git'
)
md5sums=(
	'SKIP'
	'SKIP'
)
provides=('newm')
conflicts=('newm')

pkgver() {
    cd $srcdir/newm
    newm_v=$(git describe --tags --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g')
    cd $srcdir/pywm
    pywm_v=$(git rev-parse --short HEAD)
    echo "$newm_v.$pywm_v"
}
prepare() {
    cd $srcdir/pywm
    git submodule init
    git submodule update
}
build() {
    cd $srcdir/pywm
    python3 setup.py build
    cd $srcdir/newm
    python3 setup.py build
}
package() {
    cd $srcdir/pywm
    python3 setup.py install --root="$pkgdir" --optimize=1
    cd $srcdir/newm
    python3 setup.py install --root="$pkgdir" --optimize=1
    install -Dm644 "$srcdir/newm/newm/resources/newm.desktop" "$pkgdir/usr/share/wayland-sessions/newm.desktop"
}