blob: fa3c74c03b12f4e9a6c4eb7a28d5b09585f1a0f0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Carlos Galindo <arch -at- cgj.es>
# Previous Maintainer: Jonas Heinrich <onny@project-insanity.org>
# Contributor: Jonas Heinrich <onny@project-insanity.org>
pkgname=nextcloud-app-cospend
pkgver=1.4.1
pkgrel=1
pkgdesc="Shared budget manager Nextcloud app"
arch=('any')
url="https://github.com/eneiluj/cospend-nc"
license=('AGPL3')
depends=('nextcloud>=20.0.0')
# node-sass (dependency) can't be built with node16, see https://github.com/nodejs/node/issues/38367
makedepends=('npm' 'nodejs<16' 'rsync')
options=('!strip')
source=("cospend-nc-v$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('64f20bf53e609561c7f4fec4978ea3e25284aadff279c48c454fdfedbeef7dc6db8ccc153ad8e3754f7d54013bb2a697b0fae6ebdcd6ffa309c1a8b370e7bf91')
_releasename=cospend-nc
_appname=cospend
prepare() {
cd "$srcdir/$_releasename-$pkgver"
sed -i 's/sudo rm/rm/' makefile
sed -i 's/^GITHUB_TOKEN :=/#GITHUB_TOKEN :=/' makefile
}
build() {
cd "$srcdir/$_releasename-$pkgver"
make
}
package() {
cd "$srcdir/$_releasename-$pkgver"
_destdir="$pkgdir/usr/share/webapps/nextcloud/apps"
make build_dir=build sign_dir="$_destdir" version="v$pkgver" build_release
# Remove auxiliary script
rm -f "$_destdir/$_appname/l10n/descriptions/gen_info.xml.sh"
# Remove references to $srcdir from *.js.map
find "$pkgdir" -type f -name "*.js.map" | while read file; do
sed -i "s|$srcdir|/|g" $file
done
}
|