blob: c04a3a08f69c68068b0e480dd3e11808edebcdf0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Carlos Galindo <arch -at- cgj.es>
# Previous Maintainer: Jonas Heinrich <onny@project-insanity.org>
# Contributor: Jonas Heinrich <onny@project-insanity.org>
pkgname=nextcloud-app-cospend
pkgver=1.3.0
pkgrel=1
pkgdesc="Shared budget manager Nextcloud app"
arch=('any')
url="https://github.com/eneiluj/cospend-nc"
license=('AGPL3')
depends=('nextcloud>=20.0.0')
makedepends=('npm')
options=('!strip')
source=("cospend-nc-v$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('2ea58919e3aadd045c545f956d40570a671856be4d1215da36078e6dee6aa20d2be6cd964a81e9e2a44e6396908580caa557e1dbbf360f36ae8494013c8e3e25')
_releasename=cospend-nc
_appname=cospend
prepare() {
cd "$srcdir/$_releasename-$pkgver"
sed -i 's/sudo rm/rm/' makefile
sed -i 's/^GITHUB_TOKEN :=/#GITHUB_TOKEN :=/' makefile
}
build() {
cd "$srcdir/$_releasename-$pkgver"
make
}
package() {
cd "$srcdir/$_releasename-$pkgver"
_destdir="$pkgdir/usr/share/webapps/nextcloud/apps"
make build_dir=build sign_dir="$_destdir" version="v$pkgver" build_release
# Remove auxiliary script
rm -f "$_destdir/$_appname/l10n/descriptions/gen_info.xml.sh"
# Remove references to $srcdir from *.js.map
find "$pkgdir" -type f -name "*.js.map" | while read file; do
sed -i "s|webpack://$_appname/$srcdir/$_releasename-$pkgver/node_modules|webpack://$_appname/./node_modules|" $file
done
}
|