blob: 29f59b4f8a9d8e213cb50481f612096f476c9a96 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Graham Edgecombe <gpe@grahamedgecombe.com>
pkgname=nextpnr-git
pkgver=r1185.1c1fd99
pkgrel=1
pkgdesc='Portable FPGA place and route tool'
arch=('i686' 'x86_64')
url='https://github.com/YosysHQ/nextpnr'
license=('ISC')
depends=('boost-libs' 'python' 'qt5-base')
makedepends=('boost' 'cmake' 'git' 'icestorm')
provides=('nextpnr')
conflicts=('nextpnr')
source=('nextpnr::git+https://github.com/YosysHQ/nextpnr.git')
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/nextpnr"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "$srcdir/nextpnr"
mkdir -p build
cd build
cmake \
-DARCH=generic\;ice40 \
-DICEBOX_ROOT=/usr/share/icebox \
-DBUILD_TESTS=ON \
-DCMAKE_BUILD_TYPE=RelWithDebInfo \
-DCMAKE_INSTALL_PREFIX=/usr \
..
make
}
check() {
cd "$srcdir/nextpnr/build"
make test
}
package() {
cd "$srcdir/nextpnr/build"
make DESTDIR="$pkgdir" install
install -Dm644 ../COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
|