blob: 555c25f6097fb63babd93192cd726c878d9f98d6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Máté Eckl <ecklm94@gmail.com>
# Contributor: Anatol Pomozov <anatol.pomozov@gmail.com>
# Contributor: Steven Allen <steven@stebalien.com>
pkgname=nftables-git
pkgver=0.9.2
pkgrel=2
pkgdesc='Netfilter tables userspace tools'
arch=(i686 x86_64)
url='https://netfilter.org/projects/nftables/'
license=('GPL2')
depends=(libmnl libnftnl-git gmp readline ncurses jansson)
makedepends=(asciidoc git bison flex)
provides=(nftables)
conflicts=(nftables)
source=(git://git.netfilter.org/nftables
nftables.conf
nftables.service)
sha1sums=('SKIP'
'7869aa31ac802922073310ffd4cbbc16450171e5'
'59185e947ebfd599954800ad2c774171b3f4cd58')
pkgver() {
cd nftables
git describe | sed 's/^v//; s/-/.r/; s/-/./'
}
build() {
cd nftables
sh autogen.sh
./configure \
--prefix=/usr \
--sbindir=/usr/bin \
--sysconfdir=/usr/share \
--with-json \
--with-python-bin=''
make
}
package() {
cd nftables
make DESTDIR="$pkgdir" install
# basic safe firewall config
install -Dm644 "$srcdir/nftables.conf" "$pkgdir/etc/nftables.conf"
# systemd
install -Dm644 "$srcdir/nftables.service" "$pkgdir/usr/lib/systemd/system/nftables.service"
}
|