blob: d63ad4a0805895fa3ffdeffe4744c115544ecdb7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Shaun Bouckaert <shaun@train-meditations.com>
# Contributor: francoism90
# Contributor: Anatol Pomozov
# Contributor: Zhuoyun Wei <wzyboy@wzyboy.org>
pkgname=nghttp2
pkgver=1.61.0
pkgrel=1
pkgdesc='Client, server and proxy programs from the nghttp2 library'
arch=(x86_64)
url='https://nghttp2.org/'
license=(MIT)
depends=(python libev libxml2 jansson jemalloc c-ares "libnghttp2>=$pkgver" systemd-libs)
options=(!emptydirs)
source=(https://github.com/nghttp2/nghttp2/releases/download/v$pkgver/nghttp2-$pkgver.tar.xz)
backup=(
etc/nghttpx/nghttpx.conf
etc/logrotate.d/nghttpx
)
sha256sums=('c0e660175b9dc429f11d25b9507a834fb752eea9135ab420bb7cb7e9dbcc9654')
build() {
cd nghttp2-$pkgver
autoreconf -i
./configure \
--prefix=/usr \
--disable-examples
make
}
check() {
cd nghttp2-$pkgver
make check
}
package() {
cd nghttp2-$pkgver
make DESTDIR="$pkgdir" install
make -C lib DESTDIR="$pkgdir" uninstall
install -Dm644 contrib/nghttpx.service "$pkgdir/usr/lib/systemd/system/nghttpx.service"
install -Dm644 contrib/nghttpx-logrotate "$pkgdir/etc/logrotate.d/nghttpx"
install -Dm644 nghttpx.conf.sample "$pkgdir/etc/nghttpx/nghttpx.conf"
install -Dm644 COPYING "$pkgdir/usr/share/licenses/nghttp2/COPYING"
}
|