blob: cff4773fdc74ffc2d5fe3527a885f86bfbd3731c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
pkgname=nginx-mainline-mod-auth_pam
pkgver=1.5.1
pkgrel=1
_modname=ngx_http_auth_pam_module
_nginxver=1.11.10
pkgdesc='Nginx mainline module to use PAM for simple http authentication'
arch=('i686' 'x86_64')
depends=('nginx-mainline')
url="https://github.com/sto/ngx_http_auth_pam_module"
license=('BSD')
source=(
http://nginx.org/download/nginx-$_nginxver.tar.gz
https://github.com/sto/$_modname/archive/v$pkgver/$_modname-$pkgver.tar.gz
$_modname-critlog.patch::https://patch-diff.githubusercontent.com/raw/sto/ngx_http_auth_pam_module/pull/11.patch
)
sha256sums=('778b3cabb07633f754cd9dee32fc8e22582bce22bfa407be76a806abd935533d'
'77676842919134af88a7b4bfca4470223e3a00d287d17c0dbdc9a114a685b6e7'
'1a59787672cf9c6768cb77c31f19a870eaf556c7b28c8c22a22cf8a7013b93af')
prepare() {
cd "$srcdir"/$_modname-$pkgver
patch -p1 -i "$srcdir"/$_modname-critlog.patch
}
build() {
cd "$srcdir"/nginx-$_nginxver
./configure $(nginx -V 2>&1 | grep 'configure arguments' | sed -r 's@^[^:]+: @@') --add-dynamic-module=../$_modname-$pkgver
make modules
}
package() {
install -Dm644 "$srcdir"/$_modname-$pkgver/LICENSE \
"$pkgdir"/usr/share/licenses/$pkgname/LICENSE
cd "$srcdir"/nginx-$_nginxver/objs
for mod in *.so; do
install -Dm755 $mod "$pkgdir"/usr/lib/nginx/modules/$mod
done
}
|