blob: 1c25a41f5e9234e3779750de65fb6fe00024569b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
pkgname=nginx-mainline-mod-brotli
epoch=1
pkgver=0.1.2
pkgrel=15
_modname="ngx_${pkgname#nginx-mainline-mod-}"
_nginxver=1.17.6
pkgdesc="Brotli compression filter module for mainline nginx"
arch=('i686' 'x86_64')
depends=('nginx-mainline' 'brotli')
url="https://github.com/eustas/ngx_brotli"
license=('CUSTOM')
source=(
https://nginx.org/download/nginx-$_nginxver.tar.gz{,.asc}
https://github.com/eustas/$_modname/archive/v$pkgver/$_modname-$pkgver.tar.gz
)
validpgpkeys=(
'B0F4253373F8F6F510D42178520A9993A1C052F8' # Maxim Dounin <mdounin@mdounin.ru>
)
sha256sums=('3cb4a5314dc0ab0a4e8a7b51ae17c027133417a45cc6c5a96e3dd80141c237b6'
'SKIP'
'309af9e96c10e80f1884acea96379980979581adc287ce338f084607bd48c185')
prepare() {
cd "$srcdir"/$_modname-$pkgver
sed 's@/usr/local@/usr@' -i config
}
build() {
cd "$srcdir"/nginx-$_nginxver
./configure --with-compat --add-dynamic-module=../$_modname-$pkgver
make modules
}
package() {
install -Dm644 "$srcdir"/$_modname-$pkgver/LICENSE \
"$pkgdir"/usr/share/licenses/$pkgname/LICENSE
cd "$srcdir"/nginx-$_nginxver/objs
for mod in ngx_*.so; do
install -Dm755 $mod "$pkgdir"/usr/lib/nginx/modules/$mod
done
}
|