blob: 0d4d97efd552fbd1f8454a03b5bea231241cb536 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
pkgname=nginx-mainline-mod-ndk
pkgver=0.3.0
pkgrel=20
_modname="ngx_devel_kit"
_nginxver=1.15.5
pkgdesc="Module for mainline nginx that adds generic tools that module developers can use"
arch=('i686' 'x86_64')
depends=('nginx-mainline')
url="https://github.com/simpl/ngx_devel_kit"
license=('BSD')
source=(
https://nginx.org/download/nginx-$_nginxver.tar.gz{,.asc}
https://github.com/simpl/$_modname/archive/v$pkgver/$_modname-$pkgver.tar.gz
)
validpgpkeys=(
'B0F4253373F8F6F510D42178520A9993A1C052F8' # Maxim Dounin <mdounin@mdounin.ru>
)
sha256sums=('1a3a889a8f14998286de3b14cc1dd5b2747178e012d6d480a18aa413985dae6f'
'88e05a99a8a7419066f5ae75966fb1efc409bad4522d14986da074554ae61619')
build() {
cd "$srcdir"/nginx-$_nginxver
./configure --with-compat --add-dynamic-module=../$_modname-$pkgver
make modules
}
package() {
install -Dm644 "$srcdir"/$_modname-$pkgver/LICENSE \
"$pkgdir"/usr/share/licenses/$pkgname/LICENSE
cd "$srcdir"/nginx-$_nginxver/objs
for mod in *.so; do
install -Dm755 $mod "$pkgdir"/usr/lib/nginx/modules/$mod
done
}
|