blob: 41c2fb1f3b918a32af027c5d5a010db848ef3c84 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
pkgname=nginx-mainline-mod-njs
pkgver=0.1.14 # http://hg.nginx.org/njs/tags
pkgrel=1
_modname="${pkgname#nginx-mainline-mod-}"
_nginxver=1.13.5
pkgdesc='nginScript module for mainline nginx'
arch=('i686' 'x86_64')
depends=('nginx-mainline')
url="https://nginx.org/en/docs/njs_about.html"
license=('CUSTOM')
source=(
https://nginx.org/download/nginx-$_nginxver.tar.gz
njs-$pkgver.tar.gz::http://hg.nginx.org/njs/archive/$pkgver.tar.gz
)
sha256sums=('0e75b94429b3f745377aeba3aff97da77bf2b03fcb9ff15b3bad9b038db29f2e'
'aa0e15ee27d193f0b4990438c9886b4d17ca39058136e759547a86fd2be4cc27')
build() {
cd "$srcdir"/nginx-$_nginxver
./configure --with-compat --with-stream --add-dynamic-module=../njs-$pkgver/nginx
make modules
}
package() {
install -Dm644 "$srcdir"/njs-$pkgver/LICENSE \
"$pkgdir"/usr/share/licenses/$pkgname/LICENSE
cd "$srcdir"/nginx-$_nginxver/objs
for mod in *.so; do
install -Dm755 $mod "$pkgdir"/usr/lib/nginx/modules/$mod
done
}
|