blob: 04b0de2f1ac2526e6811b183748e32ef57db60cb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Oliver Paschke <oli.paschke@gmail.com>
pkgname=nginx-mainline-mod-auth-ldap-git
pkgver=r139.22d1e84
pkgrel=8
_modname=nginx-auth-ldap
_nginxver=1.15.12
pkgdesc='LDAP Authentication module for nginx'
arch=('i686' 'x86_64')
depends=('nginx-mainline' 'libldap')
makedepends=('git')
url="https://github.com/kvspb/nginx-auth-ldap"
license=('BSD')
source=(
https://nginx.org/download/nginx-$_nginxver.tar.gz
git+https://github.com/kvspb/nginx-auth-ldap.git
)
sha256sums=('3d5b90aa17de1700709ae4ec6c4d73d87c888b06c510391bf7104b006fdb2abe'
'SKIP')
pkgver() {
cd "$srcdir"/$_modname
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "$srcdir"/nginx-$_nginxver
./configure --with-compat --add-dynamic-module=../$_modname
make modules
}
package() {
install -Dm644 "$srcdir"/$_modname/LICENSE \
"$pkgdir"/usr/share/licenses/$pkgname/LICENSE
cd "$srcdir"/nginx-$_nginxver/objs
for mod in *.so; do
install -Dm755 $mod "$pkgdir"/usr/lib/nginx/modules/$mod
done
}
|