blob: b7bb01dd4d5eff672f7310d43e4df839ad48543d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Oliver Paschke <oli.paschke@gmail.com>
pkgname=nginx-mainline-mod-auth-ldap-git
pkgver=r145.e208153
pkgrel=4
_modname=nginx-auth-ldap
_nginxver=1.17.6
pkgdesc='LDAP Authentication module for nginx'
arch=('i686' 'x86_64')
depends=('nginx-mainline' 'libldap')
makedepends=('git')
url="https://github.com/kvspb/nginx-auth-ldap"
license=('BSD')
source=(
https://nginx.org/download/nginx-$_nginxver.tar.gz
git+https://github.com/kvspb/nginx-auth-ldap.git
)
sha256sums=('3cb4a5314dc0ab0a4e8a7b51ae17c027133417a45cc6c5a96e3dd80141c237b6'
'SKIP')
pkgver() {
cd "$srcdir"/$_modname
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "$srcdir"/nginx-$_nginxver
./configure --with-compat --with-http_ssl_module --add-dynamic-module=../$_modname
make modules
}
package() {
install -Dm644 "$srcdir"/$_modname/LICENSE \
"$pkgdir"/usr/share/licenses/$pkgname/LICENSE
cd "$srcdir"/nginx-$_nginxver/objs
for mod in *.so; do
install -Dm755 $mod "$pkgdir"/usr/lib/nginx/modules/$mod
done
}
|