blob: d226dc7b98f158b8fecc889fe78a7194699e310f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Damjan Georgievski <gdamjan@gmail.com>
_modname=nchan
pkgname=nginx-mod-$_modname
pkgver=1.2.8
pkgrel=2
pkgdesc='nchan nginx module'
arch=('i686' 'x86_64')
depends=("nginx")
makedepends=('nginx-src')
url="https://nchan.io/"
license=('MIT')
source=(
https://github.com/slact/$_modname/archive/v${pkgver}.tar.gz
)
prepare() {
mkdir -p build
cd build
ln -sf /usr/src/nginx/auto
ln -sf /usr/src/nginx/src
}
build() {
cd build
/usr/src/nginx/configure --with-compat --add-dynamic-module=../$_modname-$pkgver
make modules
}
package() {
install -Dm644 "$srcdir"/$_modname-$pkgver/LICENCE \
"$pkgdir"/usr/share/licenses/$pkgname/LICENCE
cd build/objs
for mod in ngx_*.so; do
install -Dm755 $mod "$pkgdir"/usr/lib/nginx/modules/$mod
done
}
sha256sums=('de42e8d4fef6aef9e4c7303a7480adfe9545992470a7f6be008de7a4bb64cc98')
|