blob: b46928e124e677ebe32d43ab2a7823b09ff18b80 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Roman Voropaev <voropaev.roma@gmail.com>
pkgbase='nginx-unit'
pkgname=('nginx-unitd' 'nginx-unit-python' 'nginx-unit-php' 'nginx-unit-go')
_shortname='unit'
pkgver=1.0
pkgrel=0
pkgdesc="Dynamic web application server, designed to run applications in multiple languages."
arch=('i686' 'x86_64')
url="http://unit.nginx.org/"
license=('Apache')
source=("https://unit.nginx.org/download/unit-$pkgver.tar.gz"
'unit.service')
sha256sums=('13b250032d3aeef554f5e7f67b26dc2c01b9e51f5f392cbeca44db65488ca6f1'
'SKIP')
makedepends=('php-embed' 'python' 'go')
build() {
cd "$srcdir"/$_shortname-$pkgver
./configure --prefix=/usr \
--sbindir=/usr/bin \
--modules="/usr/lib/$pkgbase" \
--state="/var/lib/$pkgbase" \
--pid="/run/$pkgbase.pid" \
--log="/var/log/$pkgbase.log" \
--control="/run/$pkgbase.control.sock"
./configure python
./configure php
./configure go --go-path=/usr/lib/go
make all
}
package_nginx-unitd() {
depends=('glibc')
cd "$srcdir"/$_shortname-$pkgver
make DESTDIR="$pkgdir" unitd-install
install -m 644 -D "$srcdir"/unit.service "$pkgdir"/usr/lib/systemd/system/unit.service
}
package_nginx-unit-python() {
depends=('nginx-unitd' 'python')
cd "$srcdir"/$_shortname-$pkgver
make DESTDIR="$pkgdir" python-install
}
package_nginx-unit-php() {
depends=('nginx-unitd' 'php-embed')
cd "$srcdir"/$_shortname-$pkgver
make DESTDIR="$pkgdir" php-install
}
package_nginx-unit-go() {
arch=('any')
depends=('nginx-unitd' 'go')
cd "$srcdir"/$_shortname-$pkgver
make DESTDIR="$pkgdir" go-install
}
|