PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: Gallifreyan <gallifreyan at protonmail dot ch>

pkgname=ngrrram-git
pkgver=1.0.3.r2.gac122c3
pkgrel=1
pkgdesc='A TUI tool to help you type faster and learn new layouts. Includes a free cat.'
arch=(
    'i686'
    'x86_64'
)
url="https://github.com/wintermute-cell/ngrrram"
license=("GPL-3.0-only")

depends=(
    'gcc-libs'
    'glibc'
)
makedepends=(
    'cargo'
    'git'
)
provides=('ngrrram')
conflicts=('ngrrram')

source=("$pkgname::git+https://github.com/wintermute-cell/ngrrram.git")
md5sums=('SKIP')

pkgver() {
    cd "$pkgname"
    git describe --tags --long --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    cd "$pkgname"
    export RUSTUP_TOOLCHAIN=stable
    cargo update
    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
    cd "$pkgname"
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    cargo build --release --frozen --all-features
}

package() {
    install -Dm755 "$pkgname/target/release/ngrrram" "$pkgdir/usr/bin/ngrrram"
}