blob: 5b4dac50d88389c653d843ad02c7c1f316eb1542 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Luca Weiss <luca (at) z3ntu (dot) xyz>
# Contributor: Konstantinos Sideris <siderisk at auth dot gr>
pkgname=nheko
pkgver=0.5.2
pkgrel=1
pkgdesc="Desktop client for the Matrix protocol"
arch=("i686" "x86_64")
url="https://github.com/mujx/nheko"
license=("GPL3")
depends=("lmdb" "qt5-multimedia" "qt5-svg" "libsodium" "boost-libs" "hicolor-icon-theme")
makedepends=("cmake" "fontconfig" "qt5-tools" "git" "boost")
source=("$pkgname-$pkgver.tar.gz::https://github.com/mujx/nheko/archive/v$pkgver.tar.gz")
sha512sums=('829d31aabd32338cb7eb8d15311b43e946b2b42e553894c7c5f76bb1a94cb5bbaa6f454d1910d8e6c4e10df5d2523d998743a39a1cc49850befce6d1897dbe37')
prepare() {
rm -f "$pkgname-$pkgver"/cmake/FindOlm.cmake
}
build() {
cd "$pkgname-$pkgver"
cmake -Hdeps -B.deps -DUSE_BUNDLED_BOOST=OFF
cmake --build .deps
cmake -H. -Bbuild -DCMAKE_BUILD_TYPE=Release \
-DLMDBXX_INCLUDE_DIR=.deps/usr/include \
-DTWEENY_INCLUDE_DIR=.deps/usr/include
cmake --build build
}
package() {
# Creating needed directories
install -dm755 "$pkgdir/usr/bin"
install -dm755 "$pkgdir/usr/share/pixmaps/"
install -dm755 "$pkgdir/usr/share/applications/"
# Program
install -Dm755 "$pkgname-$pkgver/build/nheko" "$pkgdir/usr/bin/nheko"
# Desktop launcher
install -Dm644 "$pkgname-$pkgver/resources/nheko-256.png" "$pkgdir/usr/share/pixmaps/nheko.png"
install -Dm644 "$pkgname-$pkgver/resources/nheko.desktop" "$pkgdir/usr/share/applications/nheko.desktop"
# Icons
local icon_size icon_dir
for icon_size in 16 32 48 64 128 256 512; do
icon_dir="$pkgdir/usr/share/icons/hicolor/${icon_size}x${icon_size}/apps"
install -d "$icon_dir"
install -m644 "$pkgname-$pkgver/resources/nheko-${icon_size}.png" "$icon_dir/nheko.png"
done
}
|