PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Maintainer: Kuro <kuro@kuro.sh>
pkgname=nihongolofi
pkgver=1.0.0
pkgrel=1
pkgdesc="Pomodoro timer with live Japanese lofi music"
arch=('x86_64')
url="https://github.com/kurojs/NihongoLofi"
license=('MIT')
depends=('electron>=28' 'yt-dlp' 'hicolor-icon-theme')
makedepends=('npm')
source=("$pkgname-$pkgver.tar.gz::https://github.com/kurojs/NihongoLofi/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('SKIP')

prepare() {
    cd "$srcdir/NihongoLofi-$pkgver"
    npm install --omit=dev
}

package() {
    cd "$srcdir/NihongoLofi-$pkgver"

    local install_dir="/usr/lib/$pkgname"
    install -dm755 "$pkgdir$install_dir"
    install -dm755 "$pkgdir/usr/share/applications"
    install -dm755 "$pkgdir/usr/share/icons/hicolor/256x256/apps"

    cp -dr --no-preserve=ownership \
        src/ package.json package-lock.json \
        "$pkgdir$install_dir/"

    # Binaries (yt-dlp bundled for Windows only — Linux uses system package)
    install -dm755 "$pkgdir$install_dir/bin"
    cp -dr --no-preserve=ownership bin/yt-dlp.exe "$pkgdir$install_dir/bin/"

    # Desktop entry
    cat > "$pkgdir/usr/share/applications/$pkgname.desktop" << EOF
[Desktop Entry]
Name=NihongoLofi
Comment=$pkgdesc
Exec=/usr/bin/$pkgname
Icon=$pkgname
Terminal=false
Type=Application
Categories=Utility;Audio;
StartupWMClass=NihongoLofi
EOF

    # Icon
    install -Dm644 build/icon.png "$pkgdir/usr/share/icons/hicolor/256x256/apps/$pkgname.png"

    # Launcher
    install -Dm755 /dev/stdin "$pkgdir/usr/bin/$pkgname" <<'EOF'
#!/bin/sh
exec /usr/bin/electron /usr/lib/nihongolofi "$@"
EOF
}