PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: hiruocha <hiruocha at gmail dot com>

pkgname=nipaplay-reload-bin
pkgver=1.1.4
pkgrel=1
pkgdesc="一个现代化的跨平台视频播放器"
arch=('x86_64')
url="https://github.com/MCDFsteve/NipaPlay-Reload"
license=('MIT')
depends=('gtk3' 'libpulse' 'alsa-lib' 'mesa')
provides=("${pkgname%-bin}=${pkgver}")
conflicts=("${pkgname%-bin}")
options=('!debug')
source=(
    "${pkgname%-bin}-${pkgver}-${CARCH}.tar.gz::${url}/releases/download/v${pkgver}/NipaPlay-${pkgver}-Linux-amd64.tar.gz"
    "${pkgname%-bin}.png::${url}/raw/main/icon_windows2linux.png"
    "${pkgname%-bin}.desktop"
)
sha256sums=(
    'd0fbae0c3e2c0addc143a8b66592c57393aa37f2318e6c92258e1d83ae46cc34'
    'de29fa53adecccf8db96197f042793324350650eae62cf2179dc51ab7b665470'
    'c2d36d469bf147500c8ac34ecc871e7e932998023a106a942010d20aa69a4146'
)

package() {
    install -Dm755 "NipaPlay" "${pkgdir}/usr/lib/${pkgname%-bin}/NipaPlay"
    install -Dm755 "run.sh" "${pkgdir}/usr/lib/${pkgname%-bin}/run.sh"

    cp -rp "lib" "${pkgdir}/usr/lib/${pkgname%-bin}/"
    cp -rp "data" "${pkgdir}/usr/lib/${pkgname%-bin}/"

    mkdir -p "${pkgdir}/usr/bin"
    ln -s "/usr/lib/${pkgname%-bin}/run.sh" "${pkgdir}/usr/bin/${pkgname%-bin}"

    install -Dm644 "${srcdir}/${pkgname%-bin}.desktop" "${pkgdir}/usr/share/applications/${pkgname%-bin}.desktop"
    install -Dm644 "${srcdir}/${pkgname%-bin}.png" "${pkgdir}/usr/share/pixmaps/${pkgname%-bin}.png"
}