blob: 7ab788691d75069c4b16eb72d1202b37e231097e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Shorin <fcl709@outlook.com>
# Contributor: cosmo <aur@dawnson.is>
# Contributor: FreeFull <jazz2rulez@gmail.com>
# Contributor: Julius Michaelis <gitter@liftm.de.de>
# Contributor: Nebulosa <nebulosa2007-at-yandex-dot-ru>
: ${_sccache:=}
pkgname=niri-shorin-fork-git
_pkgname=niri
pkgver=26.04.r87.gad55ebb
pkgrel=2
pkgdesc="Niri fork with grid, cursor enlarge, magnifier, SVG cursors, SHM screencast etc."
arch=(x86_64 aarch64)
url="https://github.com/SHORiN-KiWATA/niri"
license=(GPL-3.0-or-later)
depends=(cairo glib2 libdisplay-info libinput libpipewire libxkbcommon mesa pango pixman seatd)
makedepends=(clang rust git)
[[ -n "${_sccache}" ]] && makedepends+=(sccache)
optdepends=('fuzzel: application launcher similar to rofi drun mode'
'waybar: highly customizable Wayland bar'
'alacritty: a cross-platform OpenGL terminal emulator'
'mako: notification daemon for Wayland'
'swaybg: wallpaper tool for Wayland compositors'
'swaylock: screen locker for Wayland'
'xdg-desktop-portal-gtk: implements most of the basic functionality'
'xdg-desktop-portal-gnome: screencasting support'
'gnome-keyring: implements the secret portal, for certain apps to work'
'polkit-gnome: when apps need to ask for root permissions')
provides=("${_pkgname}=${pkgver}" "${_pkgname}-git=${pkgver}")
conflicts=("${_pkgname}" "${_pkgname}-git" "${_pkgname}-bin")
options=(!debug !lto !strip)
source=("${_pkgname}::git+https://github.com/SHORiN-KiWATA/niri.git")
b2sums=('SKIP')
pkgver() {
cd "${_pkgname}"
git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}
prepare() {
cd "${_pkgname}"
export CARGO_HOME="${srcdir}/${_pkgname}/.cargo"
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "${_pkgname}"
export CARGO_ENCODED_RUSTFLAGS="--remap-path-prefix=${srcdir}=/"
[[ -n "${_sccache}" ]] && export RUSTC_WRAPPER=sccache
export CARGO_HOME="${srcdir}/${_pkgname}/.cargo"
export CARGO_TARGET_DIR=target
cargo build --frozen --release
}
package() {
cd "${_pkgname}"
install -Dm755 "target/release/${_pkgname}" -t "${pkgdir}/usr/bin/"
install -Dm755 "resources/${_pkgname}-session" -t "${pkgdir}/usr/bin/"
install -Dm644 resources/default-config.kdl -t "${pkgdir}/usr/share/doc/niri"
install -Dm644 "resources/${_pkgname}.desktop" -t "${pkgdir}/usr/share/wayland-sessions/"
install -Dm644 "resources/${_pkgname}-portals.conf" -t "${pkgdir}/usr/share/xdg-desktop-portal/"
install -Dm644 "resources/${_pkgname}"{.service,-shutdown.target} -t "${pkgdir}/usr/lib/systemd/user/"
}
|