PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: Lysec <itslysec@gmail.com>
# Co-Maintainer: Kevin <github@kev314.dev>
pkgname=noctalia-shell-git
pkgver=2.3.1.r16.g330eac0
pkgrel=2
pkgdesc="A sleek and minimal desktop shell thoughtfully crafted for Wayland, built with Quickshell. (git version)"
arch=('any')
url="https://github.com/noctalia-dev/noctalia-shell"
license=('MIT')
depends=(
  'quickshell'
  'imagemagick'
  'brightnessctl'
  'ffmpeg'
  'qt6-multimedia'
  'python'
)
optdepends=(
  'cliphist: For clipboard history support'
  'cava: Audio visualizer component'
  'wlsunset: For supporting NightLight'
  'power-profiles-daemon: For power profile management'
  'ddcutil: For external display brightness control'
)
makedepends=('git')
provides=('noctalia-shell')
conflicts=('noctalia-shell')
install="${pkgname}.install"
source=("git+$url.git")
sha256sums=('SKIP')

pkgver() {
    cd "$srcdir/noctalia-shell"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}

package() {
  cd "$srcdir/noctalia-shell"
  
  install -dm755 "$pkgdir/etc/xdg/quickshell/noctalia-shell"
  cp -r ./* "$pkgdir/etc/xdg/quickshell/noctalia-shell/"
  
  install -Dm644 "Assets/Services/systemd/noctalia.service" \
    "$pkgdir/usr/lib/systemd/user/noctalia.service"
}