blob: 92a2f2ce88f464f60a4bb164c77f94de6ca02836 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# Maintainer: Mario Finelli <mario at finel dot li>
_npmname=clean-css-cli
pkgname=nodejs-$_npmname
pkgver=5.6.0
pkgrel=1
pkgdesc="The command line interface to clean-css CSS optimizer"
arch=(any)
url=https://github.com/jakubpawlowicz/clean-css-cli
license=(MIT)
depends=(nodejs)
makedepends=(npm)
source=(https://registry.npmjs.org/$_npmname/-/$_npmname-$pkgver.tgz)
noextract=($_npmname-$pkgver.tgz)
sha256sums=('7d86dc2c334d939d164da39e1eb7ac6b895dff465c63ca2635dd58a2dbb3bf20')
package() {
npm install --global \
--cache "$srcdir/.npm-cache" \
--prefix "$pkgdir/usr" \
"$srcdir"/$_npmname-$pkgver.tgz
find "$pkgdir/usr" -type d -exec chmod 755 '{}' +
# npm gives ownership of ALL FILES to build user
# https://bugs.archlinux.org/task/63396
chown -R root:root "${pkgdir}"
install -Dm0644 "$pkgdir/usr/lib/node_modules/$_npmname/LICENSE" \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim: set ts=2 sw=2 et:
|