blob: 7a5ef5786d8be66f15b6d6941521f19e7dfba463 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Mario Finelli <mario at finel dot li>
_npmname=clean-css-cli
pkgname=nodejs-$_npmname
pkgver=5.2.1
pkgrel=1
pkgdesc="The command line interface to clean-css CSS optimizer"
arch=(any)
url=https://github.com/jakubpawlowicz/clean-css-cli
license=(MIT)
depends=(nodejs)
makedepends=(jq npm)
source=(https://registry.npmjs.org/$_npmname/-/$_npmname-$pkgver.tgz)
noextract=($_npmname-$pkgver.tgz)
sha256sums=('f954a3788c4595fa4686f74b3a21ee4bb72771fa9282938cde17fb9c208bec94')
package() {
npm install \
--cache "$srcdir/.npm-cache" \
--user root --global \
--prefix "$pkgdir/usr" \
"$srcdir"/$_npmname-$pkgver.tgz
find "$pkgdir/usr" -type d -exec chmod 755 '{}' +
# npm gives ownership of ALL FILES to build user
# https://bugs.archlinux.org/task/63396
chown -R root:root "${pkgdir}"
find "$pkgdir" -name package.json -print0 | xargs -r -0 sed -i '/_where/d'
local tmppackage="$(mktemp)"
local pkgjson="$pkgdir/usr/lib/node_modules/$_npmname/package.json"
jq '.|=with_entries(select(.key|test("_.+")|not))' "$pkgjson" > "$tmppackage"
mv "$tmppackage" "$pkgjson"
chmod 0644 "$pkgjson"
install -Dm0644 "$pkgdir/usr/lib/node_modules/$_npmname/LICENSE" \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim: set ts=2 sw=2 et:
|