blob: 3307fbb4ae61f9c183f0addaff977abfcea32999 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
|
# Maintainer: Rafael Ascensão <rafa dot almas at gmail dot com>
_npmname='@google/clasp'
pkgname="nodejs-google-clasp"
pkgver=2.2.1
pkgrel=1
pkgdesc='Develop Apps Script Projects locally'
arch=('any')
url='https://github.com/google/clasp'
license=('Apache')
depends=('nodejs')
makedepends=('npm')
optdepends=('typescript: autocompletion and linting')
source=("https://registry.npmjs.org/$_npmname/-/${_npmname##*/}-$pkgver.tgz")
noextract=("${_npmname##*/}-$pkgver.tgz")
sha256sums=('971a7eca0e17599e4659e3344b1e8c9f2343cb181d7843ea8a6f9a42249c2809')
package() {
cd $srcdir
npm install -g --user root --prefix "$pkgdir"/usr "${_npmname##*/}-$pkgver.tgz"
# Non-deterministic race in npm gives 777 permissions to random directories.
# See https://github.com/npm/npm/issues/9359 for details.
find "${pkgdir}"/usr -type d -exec chmod 755 {} +
# Rename command because clasp from [community] has /usr/bin/clasp
mv "${pkgdir}"/usr/bin/{,g}clasp
}
|