blob: 4b5b842a6c8a6f4094dfc225dc50d18357837073 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# SPDX-License-Identifier: AGPL-3.0
#
# Maintainer: Truocolo <truocolo@aol.com>
# Maintainer: Pellegrino Prevete <cGVsbGVncmlub3ByZXZldGVAZ21haWwuY29tCg== | base -d>
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Axel Navarro < navarroaxel at gmail >
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: James Campos <james.r.campos@gmail.com>
# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
# Contributor: Dongsheng Cai <dongsheng at moodle dot com>
# Contributor: Masutu Subric <masutu.arch at googlemail dot com>
# Contributor: TIanyi Cui <tianyicui@gmail.com>
pkgname=nodejs-lts-gallium
pkgver=16.13.0
pkgrel=1
pkgdesc='Evented I/O for V8 javascript'
arch=(
'x86_64'
'arm'
)
url='https://nodejs.org/'
license=('MIT')
depends=('openssl' 'zlib' 'icu' 'libuv' 'libnghttp2' 'c-ares') # 'http-parser' 'v8')
makedepends=('python' 'procps-ng')
optdepends=('npm: nodejs package manager'
'corepack: zero-runtime-dependency package acting as bridge between Node projects and their package managers.')
provides=("nodejs=$pkgver")
conflicts=(nodejs)
source=("https://github.com/nodejs/node/archive/v$pkgver/nodejs-$pkgver.tar.gz"
system-c-ares.patch)
sha512sums=('0be8e2d427567910bfc986a6d98cff2351811ef9fc22f42a4625d58df958ed5b19d13fd09fbceb997d46582206e5f6ae4b79153870bb151c72062b9aaadb5a1c'
'bca85b5a4622b38f20f3787bdb2784db76cd4b213fadf8a5813a375080e7481c4aff7556712d59df3e19849a7eb6b2f048a69b4e2162cb717ab1b3a791d2558e')
prepare() {
patch -d node-$pkgver -Rp1 < system-c-ares.patch
}
build() {
cd node-$pkgver
./configure \
--prefix=/usr \
--with-intl=system-icu \
--without-npm \
--shared-openssl \
--shared-zlib \
--shared-libuv \
--experimental-http-parser \
--shared-nghttp2 \
--shared-cares
# --shared-v8
# --shared-http-parser
make
}
check() {
cd node-$pkgver
make test || :
}
package() {
cd node-$pkgver
make DESTDIR="$pkgdir" install
install -D -m644 LICENSE \
"$pkgdir"/usr/share/licenses/nodejs/LICENSE
}
# vim:set sw=2 sts=-1 et:
|