blob: f84fe087fe856b23479a77cd6144f1cc8089c705 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
_npmname=nativefier
_npmver=43.0.1
pkgname=nodejs-nativefier
pkgver=$_npmver
pkgrel=2
pkgdesc="Wrap web apps natively"
arch=(any)
url="https://github.com/nativefier/nativefier#readme"
license=('MIT')
depends=('nodejs' 'unzip')
makedepends=('jq' 'npm')
optdepends=()
source=(http://registry.npmjs.org/$_npmname/-/$_npmname-$_npmver.tgz)
sha1sums=('1e285984756b50d08e916e75b655eda22102c4fc')
noextract=("$_npmname-$_npmver.tgz")
package() {
# Thanks jeremejevs and je-vv for the pointers on these!
npm install -g --cache "${srcdir}/npm-cache" --prefix "$pkgdir/usr" "$srcdir/$_npmname-$pkgver.tgz"
# Fix permissions
find "$pkgdir"/usr -type d -exec chmod 755 {} +
# npm gives ownership of ALL FILES to build user
# https://bugs.archlinux.org/task/63396
chown -R root:root "${pkgdir}"
# Remove references to pkgdir
find "$pkgdir" -type f -name package.json -print0 | xargs -0 sed -i "/_where/d"
# Remove references to srcdir
local tmppackage="$(mktemp)"
local pkgjson="$pkgdir/usr/lib/node_modules/$_npmname/package.json"
jq '.|=with_entries(select(.key|test("_.+")|not))' "$pkgjson" > "$tmppackage"
mv "$tmppackage" "$pkgjson"
chmod 644 "$pkgjson"
}
# vim:set ts=2 sw=2 et:
|