blob: bbcbee7d6cc8be5711fc1b658ab5d7b402bcd264 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Laurent Zhu <laurent.zhu@epita.fr>
# Contributor: Kevin Houdebert <kevin@qwazerty.eu>
_pkgname=nolimips
pkgname=${_pkgname}-git
pkgver=0.11
pkgrel=1
pkgdesc='Nolimips is a MIPS-based simulator with "infinitely many registers".'
url="https://www.lrde.epita.fr/wiki/Nolimips"
arch=('x86_64' 'i686')
license=('GPL3')
makedepends=('git' 'python2')
depends=()
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git+https://gitlab.lrde.epita.fr/tiger/$_pkgname.git")
md5sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
git describe --always | sed 's|nolimips-||;s|-|.|g'
}
build() {
cd "$srcdir/$_pkgname"
# change interpreter with python2
find . -name '*.py' | xargs sed -i 's/python$/python2/'
./bootstrap
./configure --prefix=/usr
make
}
package() {
cd "$srcdir/$_pkgname"
make DESTDIR="$pkgdir" install
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
check() {
cd "$srcdir/$_pkgname"
make check
}
# vim:set sts=2 sw=2 et:
|