PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68

# Maintainer: Grey-007 <https://github.com/Grey-007>

pkgname=nolio
pkgver=0.5.0
pkgrel=1
pkgdesc="Minimal calendar-based todo app built with Flutter"
arch=('x86_64')
url="https://github.com/Grey-007/nolio"
license=('MIT')

depends=(
  gtk3
  glib2
  libepoxy
  libxkbcommon
  libglvnd
  mesa
  pango
  cairo
  gdk-pixbuf2
  at-spi2-core
  gcc-libs
)

makedepends=(
  git
  flutter
  clang
  cmake
  ninja
  pkgconf
)

provides=('nolio')
conflicts=('nolio-bin')

source=("git+https://github.com/Grey-007/nolio.git#tag=v$pkgver")
sha256sums=('SKIP')

prepare() {
  cd "$srcdir/$pkgname"
  flutter pub get
}

build() {
  cd "$srcdir/$pkgname"
  flutter build linux --release
}

package() {
  cd "$srcdir/$pkgname/build/linux/x64/release/bundle"

  install -dm755 "$pkgdir/usr/lib/nolio"
  cp -a . "$pkgdir/usr/lib/nolio/"

  chmod +x "$pkgdir/usr/lib/nolio/nolio"

  install -dm755 "$pkgdir/usr/bin"
  ln -s /usr/lib/nolio/nolio "$pkgdir/usr/bin/nolio"

  install -Dm644 \
    "$srcdir/$pkgname/linux/assets/icon.png" \
    "$pkgdir/usr/share/icons/hicolor/256x256/apps/nolio.png"

  install -Dm644 \
    "$srcdir/$pkgname/linux/nolio.desktop" \
    "$pkgdir/usr/share/applications/nolio.desktop"
}