PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer: TheKing <archlinux.mourner080@passmail.net>
# PKGBUILD Repo: https://codeberg.org/TheKing6488/NoRisk-Client-Lanucher-AUR
pkgname=norisk-client-launcher-nvidia
pkgver=r1263.4e73192
pkgrel=1
pkgdesc='Norisk Minecraft Client Launcher git package'
arch=("x86_64")
url="https://norisk.gg/"
license=('GPL-3.0-only')
depends=('cairo' 'gdk-pixbuf2' 'glib2' 'gtk3' 'hicolor-icon-theme' 'libsoup3' 'glibc' 'bzip2' 'gcc-libs' 'openssl' 'xz')
makedepends=('git' 'libappindicator-gtk3' 'librsvg' 'base-devel' 'rust' 'nodejs' 'clang' 'lld' 'webkit2gtk-4.1' 'yarn')
conflicts=("noriskclient-launcher" 'no-risk-client-bin' 'no-risk-client' 'noriskclient-launcher-git' 'norisk-client-launcher')
source=('nrclauncher::git+https://github.com/NoRiskClient/noriskclient-launcher.git' 'norisk-launcher.desktop' 'wrapper.sh')
sha256sums=('SKIP' '97317766cacfab18b7ee0b485bc8ed0193c37060ef0e925b96e486461c151082' 'c04ef79b98d257a3eb008aa97ec399b910fec9842621374ed489956a76aaa534')

pkgver() {
	cd "$srcdir/nrclauncher"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "$srcdir/nrclauncher"
	yarn install --frozen-lockfile
	env RUSTFLAGS="-Clinker=clang -Clink-arg=-fuse-ld=lld" CC=clang yarn run tauri build -- --no-bundle
}

package() {
	cd "$srcdir/nrclauncher/src-tauri/target/release"
	# Binary
	install -Dm755 noriskclient-launcher-v3 "$pkgdir"/usr/bin/noriskclient-launcher-v3
	# Wrapper
	install -Dm755 "$srcdir/wrapper.sh" "$pkgdir/usr/bin/norisk-client"
	# Desktop
	install -Dm755 "$srcdir/norisk-launcher.desktop" "$pkgdir/usr/share/applications/norisk-launcher.desktop"
	# License
    install -Dm644 "$srcdir/nrclauncher/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
	# Icon
	install -Dm644 "$srcdir/nrclauncher/src-tauri/icons/128x128@2x.png" "$pkgdir/usr/share/icons/hicolor/128x128/apps/noriskclient-launcher-v3.png"
}