blob: 7b89a4af0c486309cbd3bc9856a0a33fb8625928 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Gino O. <aur@1337.io>
# Upstream canonical: https://git.iris.to/#/npub1xdhnr9mrv47kkrn95k6cwecearydeh8e895990n3acntwvmgk2dsdeeycm/nostr-vpn
# GitHub below is the upstream-maintained mirror used for clickable links and release artifacts.
pkgname=nostr-vpn-bin
_pkgname=nostr-vpn
pkgver=4.1.7
pkgrel=1
pkgdesc='GTK4/libadwaita desktop client for Nostr VPN, a Tailscale-style private mesh VPN (prebuilt)'
arch=('x86_64')
url='https://github.com/mmalmi/nostr-vpn'
license=('MIT')
depends=(
'gtk4'
'libadwaita'
'glib2'
'cairo'
'zbar'
'curl'
'xdg-utils'
'nostr-vpn-cli'
)
provides=("nostr-vpn=${pkgver}")
conflicts=('nostr-vpn' 'nostr-vpn-git')
source=(
"${pkgname}-${pkgver}.deb::https://github.com/mmalmi/nostr-vpn/releases/download/v${pkgver}/nostr-vpn-v${pkgver}-linux-x64.deb"
'LICENSE'
)
sha256sums=(
'c787ebaa56b6e302ddda7c1a3f3d8ec704e5fbba50e8bb4c1e9d0f73edeeecf8'
'0db560024163fbcc5ee5cff1971684ca448da90088f341db083a38548846c3d5'
)
prepare() {
cd "${srcdir}"
rm -rf data
install -d data
bsdtar -xOf "${pkgname}-${pkgver}.deb" data.tar.xz | bsdtar -xf - -C data
}
package() {
cd "${srcdir}/data"
install -Dm755 usr/bin/${_pkgname} "${pkgdir}/usr/bin/${_pkgname}"
install -Dm644 usr/share/applications/${_pkgname}.desktop \
"${pkgdir}/usr/share/applications/${_pkgname}.desktop"
local size
for size in 16 22 24 32 48 64 128 256 512; do
install -Dm644 "usr/share/icons/hicolor/${size}x${size}/apps/${_pkgname}.png" \
"${pkgdir}/usr/share/icons/hicolor/${size}x${size}/apps/${_pkgname}.png"
done
install -Dm644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|