blob: 4cfc890fe1c4795600ec34c93bd8c01302a75423 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
# Maintainer: zxp19821005 <zxp19821005 at 163 dot com>
# Contributor: begin-theadventure <begin-thecontact.ncncb at dralias dot com>
# Contributor: joelvaz0x01 <joelvaz dot whitehat at gmail dot com>
# Contributor: Dawid Weglarz <dawid.weglarz95@gmail.com>
# Contributor: candroid_man <candroid_man@protonmail.com>
# Contributor: Ada <adadonderr@gmail.com>
# Contributor: Christian Finnberg <christian@finnberg.net>
pkgname=notesnook
pkgver=2.6.17
_electronversion=25
_nodeversion=16
pkgrel=1
pkgdesc="A fully open source & end-to-end encrypted note taking alternative to Evernote"
arch=(
'aarch64'
'x86_64'
)
url="https://notesnook.com/"
_ghurl="https://github.com/streetwriters/notesnook"
license=('GPL-3.0-or-later')
provides=("${pkgname}=${pkgver}")
conflicts=("${pkgname}")
depends=(
"electron${_electronversion}-bin"
)
makedepends=(
'nvm'
'npm'
'git'
'zip'
'base-devel'
'gcc'
'curl'
)
source=(
"${pkgname}.git::git+${_ghurl}.git#tag=v${pkgver}"
"${pkgname}.desktop"
"${pkgname}.sh"
)
sha256sums=('SKIP'
'102a538ee9432310d854842a578cd3371df0431b4db617479de66aa45b5f2440'
'dc0c5ca385ad81a08315a91655c7c064b5bf110eada55e61265633ae198b39f8')
_ensure_local_nvm() {
export NVM_DIR="${srcdir}/.nvm"
source /usr/share/nvm/init-nvm.sh || [[ $? != 1 ]]
nvm install "${_nodeversion}"
nvm use "${_nodeversion}"
}
build() {
sed -e "s|@electronversion@|${_electronversion}|" \
-e "s|@appname@|${pkgname}|g" \
-e "s|@runname@|app|g" \
-e "s|@options@||g" \
-i "${srcdir}/${pkgname}.sh"
_ensure_local_nvm
export npm_config_build_from_source=true
export npm_config_cache="${srcdir}/.npm_cache"
export ELECTRON_SKIP_BINARY_DOWNLOAD=1
export SYSTEM_ELECTRON_VERSION="$(electron${_electronversion} -v | sed 's/v//g')"
export npm_config_target="${SYSTEM_ELECTRON_VERSION}"
export ELECTRONVERSION="${_electronversion}"
export npm_config_disturl=https://electronjs.org/headers
HOME="${srcdir}/.electron-gyp"
#build
cd "${srcdir}/${pkgname}.git"
if [ `curl ifconfig.co/country` = "China" ];then
echo 'registry="https://registry.npmmirror.com/"' >> .npmrc
echo 'electron_mirror="https://registry.npmmirror.com/-/binary/electron/"' >> .npmrc
echo 'electron_builder_binaries_mirror="https://registry.npmmirror.com/-/binary/electron-builder-binaries/"' >> .npmrc
else
echo "Your network is OK."
fi
# Install packages
npm ci --ignore-scripts --prefer-offline --no-audit
npm run bootstrap -- --scope=web
# Generate desktop build
npx nx build:desktop @notesnook/web
npm run bootstrap -- --scope=desktop
# Build Electron wrapper
cd "${srcdir}/${pkgname}.git/apps/desktop"
npx nx run release --project @notesnook/desktop
npx electron-builder --dir
}
package() {
install -Dm755 "${srcdir}/${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"
install -Dm755 -d "${pkgdir}/usr/lib/${pkgname}"
cp -r "${srcdir}/${pkgname}.git/apps/desktop/output/linux-"*/resources/{app,assets} "${pkgdir}/usr/lib/${pkgname}"
for _icons in 16x16 24x24 32x32 48x48 64x64 128x128 256x256 512x512 1024x1024;do
install -Dm644 "${srcdir}/${pkgname}.git/apps/desktop/assets/icons/${_icons}.png" \
"${pkgdir}/usr/share/icons/hicolor/${_icons}/apps/${pkgname}.png"
done
install -Dm644 "${srcdir}/${pkgname}.desktop" -t "${pkgdir}/usr/share/applications"
}
|