blob: 3d2f034d716948b09a63d98ca83b58ec7fc9e591 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Rafael Dominiquini <rafaeldominiquini at gmail dot com>
_upstreamver='1.17.0'
_upstreamver_regex='^[0-9]+\.[0-9]+\.[0-9]+$'
_source_type='pypi-releases'
_pypi_package='nothing-less'
_execname=nless
pkgname="${_pypi_package}"
pkgver="${_upstreamver}"
pkgrel=1
pkgdesc="A TUI paging application with enhanced support for tabular data and real-time streaming"
license=('MIT')
arch=('any')
_url_pypi='https://pypi.org/project/nothing-less/'
_url_github='https://github.com/mpryor/nothing-less'
url="${_url_github}"
provides=("${_execname}")
makedepends=('python-setuptools' 'python-wheel' 'python-build' 'python-installer' 'python-poetry' 'python-hatchling')
depends=('python' 'python-textual' 'python-packaging' 'python-rich' 'python-pyperclip')
# source=("https://files.pythonhosted.org/packages/source/${_pypi_package::1}/${_pypi_package//-/_}/${_pypi_package//-/_}-${pkgver}.tar.gz")
source=("${_pypi_package}-${_upstreamver}.tar.gz::${_url_github}/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('d031eba926f6901fa8a359998e441b6e4e0dbe28d6cc5dea162a956569517d73')
build() {
cd "${srcdir}/${_pypi_package}-${pkgver}/" || exit
python -m build --wheel --no-isolation
}
package() {
cd "${srcdir}/${_pypi_package}-${pkgver}/" || exit
python -m installer --destdir="${pkgdir}" dist/*.whl
install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|