blob: 198b749eec40ac8221e71afb0fdd0ae570e8a70f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: David Seus <archstuff at archlinux.net>
# Contributor: Vincent Szolnoky <ippytraxx at installgentoo.com>
# Contributor: Trevor Turner <turn3r.tr3v0r at gmail.com>
pkgname=ntfs-3g-fuse
pkgver=2017.3.23
pkgrel=1
pkgdesc="Stable read and write NTFS driver and ntfsprogs. This package will allow normal users to mount NTFS Volumes."
arch=('i686' 'x86_64')
url="http://www.tuxera.com/community/open-source-ntfs-3g/"
license=('GPL2')
depends=('glibc' 'libutil-linux')
conflicts=('ntfs-3g' 'ntfsprogs')
provides=('ntfsprogs' 'ntfs-3g')
options=('!libtool')
install=ntfs-3g-fuse.install
source=(http://tuxera.com/opensource/ntfs-3g_ntfsprogs-$pkgver.tgz)
sha256sums=('3e5a021d7b761261836dcb305370af299793eedbded731df3d6943802e1262d5')
prepare()
{
cd "${srcdir}/ntfs-3g_ntfsprogs-${pkgver}"
sed -i 's|$(DESTDIR)/sbin|$(DESTDIR)/usr/bin|' {ntfsprogs,src}/Makefile.in
}
build()
{
cd "${srcdir}/ntfs-3g_ntfsprogs-${pkgver}"
./configure --prefix=/usr \
--with-fuse=internal --disable-static \
--enable-posix-acls --disable-ldconfig \
--mandir=/usr/share/man --sbin=/usr/bin
make
}
package()
{
cd "${srcdir}/ntfs-3g_ntfsprogs-${pkgver}"
make DESTDIR="$pkgdir" rootbindir=/usr/bin rootsbindir=/usr/bin rootlibdir=/usr/lib install
ln -s /usr/bin/ntfs-3g "$pkgdir/usr/bin/mount.ntfs"
}
|