blob: d74b7b94949e2806f37f4c05ce161ccff4a28227 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# shellcheck shell=bash
# AUR Maintainer: Shadichy <shadichy@blisslabs.org>
pkgbase=ntfsplus-dkms-git
pkgname=("$pkgbase" "ntfsplus-udev")
pkgver=2026.06.22+640b7dd
pkgrel=1
# epoch=1
pkgdesc="A new NTFS driver for Linux promised to be better than NTFS3. Maintained out-of-tree. Backported to 5.15 LTS."
arch=('any')
url="https://github.com/namjaejeon/linux-ntfs"
license=('GPL-2.0-only')
makedepends=('git')
optdepends=(
'ntfsprogs-plus: Recommended NTFS utilities'
)
options=('!strip' '!emptydirs')
source=(
"$pkgbase::git+$url"
'Makefile'
'dkms.conf'
'00-ntfsplus.conf'
'90-udev-prefer-ntfsplus.rules'
)
sha256sums=(
SKIP
e56996db016fbf39411624590f0033fb5b1aad03f3c72feb17705552f2d482c2
df453137fe0182ab488154dfaccbbb1fc64846c7f2d5d3a3358f12decdbab602
75133e4f350ee1cdc8bc96b3fea51ab720d7a5dd9c1f5392b386489de3babf70
25f98d3070e1486d75351c38f5c2e30b4459e9e27cd5fdd45bba09eee94a684a
)
pkgver() {
cd "$srcdir/$pkgbase"
git log --format='%cd+%h' -n1 --date=format:'%Y.%m.%d'
}
package_ntfsplus-dkms-git() {
pkgdesc="DKMS module for ntfs (with aliases)."
depends=('dkms')
optdepends+=("ntfsplus-udev: udev rules for ntfsplus")
provides=('ntfsplus' 'ntfs' 'NTFSPLUS-MODULE' 'NTFS-MODULE')
conflicts=('ntfsplus' 'ntfs')
cd "$srcdir"
local dest="$pkgdir/usr/src/ntfs-${pkgver}"
mkdir -p "$dest"
cp -rpt "$dest" "$srcdir/$pkgbase/"*.{h,c} "$srcdir/$pkgbase/Kconfig"
install -Dm644 "$(readlink -f dkms.conf)" "$dest/dkms.conf"
install -Dm644 "$(readlink -f Makefile)" "$dest/Makefile"
# Install module config
mkdir -p "$pkgdir/etc/modprobe.d"
install -Dm644 "$(readlink -f 00-ntfsplus.conf)" "$pkgdir/etc/modprobe.d/"
}
package_ntfsplus-udev() {
pkgdesc="udev rules for ntfsplus."
depends=('udev')
cd "$srcdir"
local rule='90-udev-prefer-ntfsplus.rules'
install -Dm644 "$(readlink -f "$rule")" "$pkgdir/usr/lib/udev/rules.d/$rule"
}
|