blob: d932e6b64cd0222e5c26ab5c79269256f32e9176 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Hao Long <aur@esd.cc>
# Co-Maintainer: Misaka13514 <Misaka13514 at gmail dot com>
# Contributor: Caltlgin Stsodaat <contact@fossdaily.xyz>
pkgname=nuclei
pkgver=3.2.6
pkgrel=1
pkgdesc='Fast tool for configurable targeted scanning based on templates offering massive extensibility and ease of use'
arch=('x86_64' 'armv6h' 'aarch64')
url='https://github.com/projectdiscovery/nuclei'
license=('MIT')
depends=('glibc')
makedepends=('go')
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
b2sums=('d4e93522d16cccf8d77989f4d2ee3ae951b9fd23d9732681d98ccf8d5f7840128c213101cf6ca53cecbe45e45345da8a2e1ad64d678fbe42dd11d81ab81e41ae')
prepare() {
export GOPATH="${srcdir}/gopath"
go clean -modcache
}
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
cd "${pkgname}-${pkgver}"
go build -v -o "${pkgname}" ."/cmd/${pkgname}"
}
package() {
cd "${pkgname}-${pkgver}"
install -Dvm755 "${pkgname}" -t "${pkgdir}/usr/bin"
install -Dvm644 'README.md' -t "${pkgdir}/usr/share/doc/${pkgname}"
install -Dvm644 'LICENSE.md' "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim: ts=2 sw=2 et:
|